iTheme

[Jay]

I thought I would share a mIRC script I wrote a long time ago, that I still use. It's called "iTheme", and it's basically just a theme to make mIRC a little more visually appealing.

 

Features

• /e - Evaluates text to test identifiers.
  
• highlights - notifies you when you've been mentioned in a channel.
  
• GUI - Interactive window to customize colors
  

 

 

 

CODE

;;open alias

alias itheme {

if ($dialog(itheme)) { dialog -x itheme }

dialog -md itheme itheme

}

menu * {

iTheme

.Reload:themeload reload

.Open:$iif($dialog(itheme),dialog -x itheme) | dialog -md itheme itheme

}

alias themeload {

.timestamp -f $+($itc1($itbrack1),$itc2(hh),$itc1(:),$itc2(nn),$itc1(:),$itc2(ss) $itc1(TT),$itc1($itbrack2))

.font -z 12 $itfont

.color background $iif($readini(itheme.ini,settings,bg) != $null,$v1,1)

.color treebar $iif($readini(itheme.ini,settings,treebarbg) != $null,$v1,1)

.color normal text $iif($readini(itheme.ini,colors,main) != $null,$v1,14)

.color own text $iif($readini(itheme.ini,colors,main) != $null,$v1,14)

.color listbox $iif($readini(itheme.ini,settings,listboxbg) != $null,$v1,1)

.color editbox $iif($readini(itheme.ini,settings,editboxbg) != $null,$v1,1)

.color editbox text $iif($readini(itheme.ini,settings,editboxtext) != $null,$v1,14)

.color listbox text $iif($readini(itheme.ini,settings,listboxtext) != $null,$v1,14)

.color treebar text $iif($readini(itheme.ini,settings,treebartext) != $null,$v1,14)

.color treebar $iif($readini(itheme.ini,settings,treebarbg) != $null,$v1,1)

.color whois text $iif($readini(itheme.ini,settings,whoistext) != $null,$v1,14)

.color inactive $iif($readini(itheme.ini,settings,editboxbg) != $null ,$v1,1)

if (%newtrig) { echo -sta $itc1(Your) $itc2(iTheme) $itc1(alias has been updated.) }

elseif ($1 == Start) { echo -sta $itc2($ita) $itc1(Welcome to) $itc2(iTheme) $itc1(by) $itc2(Jay) $+ $itc1(.) }

elseif ($1 == Reload) { echo -sta $itc2($ita) $itc1(Your) $itc2(iTheme) $itc1(settings have been updated.) }

}

alias itcs { echo -t $1 $itc1($ita) $itc2($1) $itc1(-) $itc2($nick($1,0)) $itc1(users) $itc1($itbrack1)) $+ $itc2($nick($1,0,o)) $itc1(Ops -) $itc2($nick($1,0,h,o)) $itc1(Halfs -) $itc2($nick($1,0,v,oh)) $itc1(Voices -) $itc2($nick($1,0,r)) $itc1(Regulars $+ $itbrack2)) }

alias itfl {

var %x 1

while (%x <= $lines($script)) {

if ($read($script,%x) == ;;open alias) {

inc %x

tokenize 32 $read($script,%x)

return $2 %x

halt

} inc %x }

}

alias itlc {

set -u10 %newtrig Yes

/write $+(-l,$gettok($itfl,2,32)) $qt($script) alias $1 $chr(123)

echo -ta $itc1(The command to open your command center has been changed to) $itc2(/ $+ $1) $+ $itc1(.)

echo -ta $itc1(Please allow the script to reload.)

}

alias itheme { $iif($dialog(itheme),dialog -x itheme) | dialog -md itheme itheme }

alias itvers return 1.0

alias lll return

alias ita return $iif($readini(itheme.ini,settings,arrow),$v1,—›)

alias itbrack1 { return $iif($readini(itheme.ini,settings,brack1),$v1,$chr(40)) }

alias itbrack2 { return $iif($readini(itheme.ini,settings,brack2),$v1,$chr(41)) }

alias itc1 { return $+($chr(3),14,$1-,$chr(3)) }

alias itc2 { return $+($chr(3),10,$1-,$chr(3)) }

alias itfont { return $iif($readini(itheme.ini,settings,font),$v1,verdana) }

alias itautoid { return $iif($readini(itheme.ini,settings,autoid) == Yes,On) }

alias itpass { return $readini(itheme.ini,settings,pass) }

alias e { msg $active $+($itc2($itbrack1),$itc1(Eval),$itc2($itbrack2))) $c1($1-) $c2() $c1($($1,2)) }

ON *:START:{ themeload start }

ON *:INPUT:*: {

haltdef

if ($left($1,1) == /) {

if (/msg isin $1) {

var %t $iif($left($nick(#,$nick).pnick,1) isin $+($chr(64),$chr(37),$chr(38),$chr(126),$chr(43)),$v1)

.msg $($2,2) $3-

echo -t $iif($me ison $($2,2),$v2,$itc1($ita)) $+($itc1($itbrack1),$chr(3),$replace(%t,@,4,%,7,+,2,~,14,&,14),%t,$chr(3),$itc2($me),$itc1($itbrack2)) $3-

halt

}

if (!$ctrlenter) { $iif($left($1,2) != //,$1-,$($1-,2)) }

else { goto tuche }

}

else {

if ($chan) {

:tuche

var %t $iif($left($nick(#,$me).pnick,1) isin @%+~&,$v1,$null)

.msg $active $1-

echo -a $timestamp $+($itc1($itbrack1),$chr(3),$replace(%t,@,4,&,4,~,4,%,7,+,2),%t,$chr(3),$itc2($me),$itc1($itbrack2)) $1-

if ($regex($1,/^[+-][a-zA-Z]/Si)) { mode $chan $($1-,2) }

}

else {

echo -a $timestamp $+($itc1($itbrack1),$itc2($me),$itc1($itbrack2)) $1-

.msg $active $1-

}

}

}

ON ^*:TEXT:*:*: {

haltdef

if ($chan) {

if ($me isin $1- && $chan != $active && $nick != PW) {

echo -ta $itc1($ita) $itc2($nick) $itc1(has highlighted you in) $itc2($chan) $itc1(- ") $+ $itc2($1-) $+ $itc1(")

}

var %p $iif($left($nick(#,$nick).pnick,1) isin $+($chr(64),$chr(37),$chr(38),$chr(126),$chr(43)),$v1)

echo -t $chan $+($itc1($itbrack1),$chr(3),$iif(%p,$replace(%p,@,4,%,7,+,2,&,4,~,4),10),%p,$itc2($nick),$itc1($itbrack2)) $1-

}

else { echo -t $nick $+($itc1($itbrack1),$itc2($nick),$itc1($itbrack2)) $1- }

}

ON ^*:ACTION:*:*: {

haltdef

echo -t $iif($chan,$chan,$nick) $itc1($ita) $itc1($nick) $itc1($1-)

}

ON ^*:KICK:#: {

haltdef

if ($knick == $me) { echo -st $itc1($ita) $itc1(You were kicked from) $itc2($chan) $itc1(by) $itc1($nick) $+($itc1($itbrack1),$itc2($iif($1-,$1-,No Reason)),$itc1($itbrack2)) }

else { echo -t $chan $itc1($ita) $itc2($knick) $itc1(was kicked from) $itc2($chan) $itc1(by) $itc1($nick) $+($itc1($itbrack1),$itc2($iif($1-,$1-,No Reason)),$itc1($itbrack2)) }

}

PCR 311:*:{

haltdef

echo -tma $itc1($ita) $itc2($2) $itc1(is) $qt($itc2($6-)) $+($itc1($itbrack1),$itc2($3),$itc1(@),$itc2($4),$itc1($itbrack2))

}

PCR 319:*:{

haltdef

var %o $count($1-,$chr(64))

var %h $count($3-,$chr(37))

var %v $count($3-,+)

var %r $calc($count($3-,$chr(35))) - $calc(%o + %h + %v))

echo -ta $itc1($ita) $itc2($2) $itc1(is on) $itc2($count($3-,$chr(35))) $itc1(channel $+ $iif($count($3-,$chr(35)) > 1,s) $+ .) $itc1($itbrack1) $+ $itc1(Op in) $itc2(%o) $itc1(- HalfOp in) $itc2(%h) $itc1(- Voice in) $itc2(%v) $itc1(- Regular in) $itc2(%r) $+ $itc1($itbrack2)

tokenize 32 $3-

var %x 1

while (%x <= $gettok($1-,0,32)) {

if ($left($gettok($1-,%x,32),1) isin @~&) { var %all %all $+($chr(3),4,$left($gettok($1-,%x,32),1),$itc1($mid($gettok($1-,%x,32),2-))) }

elseif ($left($gettok($1-,%x,32),1) == $chr(37)) { var %all %all $+($chr(3),7,$chr(37),$itc1($mid($gettok($1-,%x,32),2-))) }

elseif ($left($gettok($1-,%x,32),1) == +) { var %all %all $+($chr(3),2,+,$itc1($mid($gettok($1-,%x,32),2-))) }

else { var %all %all $+($chr(3),10,-,$itc1($mid($gettok($1-,%x,32),1-))) }

inc %x

}

echo -ta $itc1($ita) %all

}

PCR 301:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(is away:) $+($itc1("),$itc2($3-),$itc1(")) }

PCR 335:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(is a) $itc2(Bot) }

PCR 312:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(is using) $itc2($3) $+($itc1($chr(40)),$itc2($4-),$itc1($chr(41))) }

PCR 313:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(is a) $itc2($5-) }

PCR 320:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(is a) $itc2($5-) }

PCR 307:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(is identified.) }

PCR 671:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(is using a) $itc2(Secure Connection) }

PCR 378:*:{ haltdef

echo -tma $itc1($ita) $itc2($2) $itc1(is connecting from) $itc2($6-)

}

PCR 317:*:{

haltdef

echo -tma $itc1($ita) $itc2($2) $itc1(has been idle for) $itc2($duration($3))

echo -tma $itc1($ita) $itc2($2) $itc1(signed on) $itc2($asctime($4))

}

PCR 310:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(is available for help.) }

PCR 332:*:{ haltdef | echo -tm $2 $itc1($ita) $itc1(Topic for) $itc2($2) $itc1(is) $+($itc1("),$3-,$itc1(")) }

PCR 401:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(- No such nick or channel.) }

PCR 333:*:{ haltdef | echo -tm $2 $itc1($ita) $itc1(Set By) $itc2($3) $itc1(-) $itc2($asctime($4)) }

PCR 482:*:{ haltdef | echo -tma $itc1($ita) $itc2($2) $itc1(- $3-) }

ON ^*:notice:*:*:{

haltdef

if ($nick == NickServ && $itpass && $1- == please choose a different nick.) { ns id $itpass }

echo -tsa $itc2($chan) $itc1($ita) $+($itc1($itbrack1),$itc2(Notice:),$itc1($itbrack2)) $+($itc1(-),$itc2($nick),$itc1(-)) $1-

}

ON ^*:snotice:*:{ haltdef | echo -tsa $itc1($ita) $itc2($server) $itc1($1-) }

ON ^*:PART:#: {

haltdef

if ($nick == $me) {

echo -satm $itc1($ita) $itc1(You have parted) $itc2($chan)

.timer. [ $+ [ $chan ] ] off

}

else { echo -tm $chan $itc1($ita) $itc2($nick) $itc1(has parted) $itc2($chan) $+($itc1($itbrack1),$itc2($iif($1-,$1-,No Reason)),$itc1($itbrack2)) }

}

ON ^*:JOIN:#: {

haltdef

if ($nick == $me) {

echo -tm $chan $itc1($ita) $itc1(You are now talking in) $itc2( $+ $chan $+ )

.timer. [ $+ [ $chan ] ] 1 2 itcs $chan

}

else { echo -tm $chan $itc1($ita) $itc2($nick) $itc1(has joined) $itc2( $+ $chan $+ ) $+($itc1($itbrack1),$itc2($address($nick,2)),$itc1($itbrack2)) }

}

on ^*:NICK: {

haltdef | var %x 1

while (%x <= $comchan($newnick,0)) {

echo -t $comchan($newnick,%x) $itc1($ita) $itc2($nick) $itc1(is now known as) $itc2($newnick)

inc %x

}

}

ON *:CONNECT:{ if ($network == SwiftIRC) join #PureWarfare }

ON ^*:TOPIC:#:{

haltdef

echo -tm $chan $itc1($ita) $itc2($nick) $itc1(has changed the topic to) $+($itc1($itbrack1),$itc2($1-),$itc1($itbrack2))

}

on ^*:rawmode:#:{

haltdef

echo -t $chan $itc1($ita) $itc2($nick) $itc1(sets mode) $itc2($1-)

}

on ^*:invite:#:{

haltdef

echo -tmsa $itc1($ita) $itc2($nick) $itc1(has invited you to) $itc2($chan)

}

on ^*:snotice:*:{

haltdef

echo -satm $itc1($ita) $+($itc1($itbrack1),$itc2(Notice:),$itc1($itbrack2)) $+($itc1(-),$itc2($nick),$itc1(-)) %tot

}

on ^*:quit: {

haltdef

var %x 1

while (%x <= $comchan($nick,0)) {

echo -t $comchan($nick,%x) $itc1($ita) $itc2($nick) $itc1(has just quit) $itc2($network) $+ $itc1(. Reason:) $itc2($iif($1- != Quit:,$1-,None.))

inc %x

}

}

PCR 318:*: { haltdef }

dialog iTheme {

title ""

size -1 -1 225 200

option dbu

 

tab "Colors",2,0 0 250 225

tab "Settings",3

 

text "Background Color",20,10 40 50 10, tab 2

combo 21, 8 50 22 10,drop, tab 2

edit "",22,32 50 20 10, tab 2

 

text "ChanList Color",25,10 80 50 10, tab 2

combo 26, 8 90 22 10, drop, tab 2

edit "",27,32 90 20 10,tab 2

 

text "Text Color",30, 10 120 50 10, tab 2

combo 31,8 130 22 10, drop, tab 2

edit "",32,32 130 20 10, tab 2

 

text "NickList Color",35,10 160 50 10, tab 2

combo 36,8 170 22 10, drop,tab 2

edit "",37,32 170 20 10,tab 2

 

text "EditBox Color",40,95 40 50 10, tab 2

combo 41, 88 50 22 10,drop, tab 2

edit "",42,112 50 20 10, tab 2

 

text "EditBox Text",45,95 80 50 10, tab 2

combo 46, 88 90 22 10,drop, tab 2

edit "",47,112 90 20 10, tab 2

 

text "Nicklist Text",50,95 120 50 10, tab 2

combo 51, 88 130 22 10,drop, tab 2

edit "",52,112 130 20 10, tab 2

 

text "ChanList Text",55,95 160 50 10, tab 2

combo 56, 88 170 22 10,drop, tab 2

edit "",57,112 170 20 10, tab 2

 

button "Update",100,185 180 30 10, tab 2

button "Reset",101,185 170 30 10, tab 2

 

text "Auto Identfiy",152, 30 41 80 8, tab 3

button "On",153,33 51 25 10, tab 3

 

text "Password",155, 20 70 40 10, tab 3

edit "",156,20 80 50 10, tab 3

button "Save",157,50 90 20 10, tab 3

 

text "Brackets",160, 130 40 40 10, tab 3

edit "",161, 155 40 25 9, tab 3

combo 162,137 50 40 10,drop, tab 3

 

text "iTheme Command",170,130 70 50 10, tab 3

edit "",171,130 80 50 10,tab 3

button "Save",172,160 90 20 10, tab 3

 

text "Arrow",180,130 120 40 10,tab 3

edit "",181,155 120 25 9, tab 3

combo 182,137 130 40 10, drop , tab 3

 

 

}

ON *:DIALOG:itheme:*:*: {

if ($devent == init) {

dialog -t itheme iTheme $+(v,$itvers)

did -m $dname 22,27,32,37,42,47,52,57,161,181

did -a $dname 22 $iif($readini(itheme.ini,settings,bg) != $null,$v1,1)

did -a $dname 27 $iif($readini(itheme.ini,settings,treebarbg) != $null,$v1,1)

did -a $dname 32 $iif($readini(itheme.ini,colors,main) != $null,$v1,14)

did -a $dname 37 $iif($readini(itheme.ini,settings,listboxbg) != $null,$v1,1)

did -a $dname 42 $iif($readini(itheme.ini,settings,editboxbg) != $null,$v1,1)

did -a $dname 47 $iif($readini(itheme.ini,settings,editboxtext) != $null,$v1,14)

did -a $dname 52 $iif($readini(itheme.ini,settings,listboxtext) != $null,$v1,14)

did -a $dname 57 $iif($readini(itheme.ini,settings,treebartext) != $null,$v1,14)

did -a $dname 153 $iif($readini(itheme.ini,settings,autoid) == Yes,On,Off)

did -a $dname 156 $iif($readini(itheme.ini,settings,pass),$v1)

did -a $dname 161 $itbrack1 $+ Text $+ $itbrack2

did -a $dname 162 (Text)

did -a $dname 162 $chr(91) $+ Text $+ $chr(93)

did -a $dname 162 -Text-

did -a $dname 162 .:Text:.

did -a $dname 162 ~Text~

did -a $dname 162 .Text.

did -a $dname 162 :Text:

did -a $dname 162 *Text*

did -a $dname 162 ^Text^

did -a $dname 171 / $+ $gettok($itfl,1,32)

did -a $dname 181 $ita

did -a $dname 182 —›

did -a $dname 182 ~

did -a $dname 182 -->

did -a $dname 182 -

var %x 0

while (%x <= 15) { did -a $dname 21,26,31,36,41,46,51,56 %x | inc %x }

}

if ($devent == sclick) {

if ($did == 21) { did -r $dname 22 | did -a $dname 22 $did(21).seltext }

if ($did == 26) { did -r $dname 27 | did -a $dname 27 $did(26).seltext }

if ($did == 31) { did -r $dname 32 | did -a $dname 32 $did(31).seltext }

if ($did == 36) { did -r $dname 37 | did -a $dname 37 $did(36).seltext }

if ($did == 41) { did -r $dname 42 | did -a $dname 42 $did(41).seltext }

if ($did == 46) { did -r $dname 47 | did -a $dname 47 $did(46).seltext }

if ($did == 51) { did -r $dname 52 | did -a $dname 52 $did(51).seltext }

if ($did == 56) { did -r $dname 57 | did -a $dname 57 $did(56).seltext }

if ($did == 100) {

var %t writeini -n itheme.ini

%t settings bg $did(22)

%t settings treebarbg $did(27)

%t colors main $did(32)

%t settings whoistext $did(32)

%t settings listboxbg $did(37)

%t settings editboxbg $did(42)

%t settings editboxtext $did(47)

%t settings listboxtext $did(52)

%t settings treebartext $did(57)

%t colors second $did(57)

themeload reload

}

if ($did == 101) {

remini itheme.ini settings

remini itheme.ini colors

themeload reload

}

if ($did == 153) {

writeini -n theme.ini settings autoid $iif($did(153) == on,off,yes)

if ($did(153) == off) { did -r $dname 153 | did -a $dname 153 On }

else { did -r $dname 153 | did -a $dname 153 Off }

}

if ($did == 157 && $did(156)) { writeini -n itheme.ini settings pass $did(156) }

if ($did == 162) {

did -r $dname 161

did -a $dname 161 $did(162).seltext

var %t $replace($did(162).seltext,text,$chr(124))

writeini -n itheme.ini settings brack1 $gettok(%t,1,124)

writeini -n itheme.ini settings brack2 $gettok(%t,2,124)

themeload reload

}

if ($did == 172 && $did(171)) { itlc $remove($did(171),/) }

if ($did == 182) {

did -r $dname 181

did -a $dname 181 $did(182).seltext

writeini -n itheme.ini settings arrow $did(182).seltext

themeload reload

}

}

}

 

 

Let me know if you have any questions about the script.

[Ded]

i use sk

[Lawson]

Nice one Jay, ill use this :)

[Jay]

If you notice, the colors (grey and blue) used in this theme are also the default colors used by the PureWarfare bot. What does this mean? The bot text will you sexy as all hell on this theme ^.^

[Martin]

mirc scripting is so oldschool

[xVideos]

Jay I <3 ur signature lol

[Anthoni]

Already have been using it for a few months now.

[Jay]

xVideos, thanks hahah.

 

 

Anthoni, that makes me happy :D